POV-Ray

The Persistence of Vision Raytracer (POV-Ray).

This is the legacy Bug Tracking System for the POV-Ray project. Bugs listed here are being migrated to our github issue tracker. Please refer to that for new reports or updates to existing ones on this system.

Tasklist

FS#95 - Photons are over-attenuated by semi-transparent surfaces

Attached to Project: POV-Ray
Opened by Christoph Lipka (clipka) - Tuesday, 13 April 2010, 10:50 GMT
Last edited by Christoph Lipka (clipka) - Saturday, 19 June 2010, 12:25 GMT
Task Type Definite Bug
Category Backend → Photons
Status Closed
Assigned To Christoph Lipka (clipka)
Operating System All
Severity High
Priority High
Reported Version 3.70 beta 36
Due in Version 3.70 beta 37
Due Date Undecided
Percent Complete 100%
Votes 0
Private No

Details

The code to attenuate transmitted photons according to surface texture was apparently duplicated during refactoring of the source code for version 3.7. Behavior has changed from 3.6 to 3.7 (beta.36) accordingly, as can be demonstrated with the following scene:

global_settings {
  assumed_gamma 1.0
  max_trace_level 10
  photons { spacing 0.02 }
}

camera {
  right x*image_width/image_height
  location  <0,2.6,-10>
  look_at   <0,0.75,0>
}

light_source {
  <500,300,150>
  color rgb 1.3
  photons {
    refraction on
    reflection on
  }
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

plane {
  y, 0
  texture { pigment { color rgb <1.0, 0.8, 0.6> } }
}

#declare M_Glass=
material {
  texture {
    pigment {rgbt 1}
    finish {
      ambient 0.0
      diffuse 0.05
      specular 0.6
      roughness 0.005
      reflection { 0.1, 1.0 fresnel on }
      conserve_energy
    }
  }
  interior {
    ior 1.5
    fade_power 1001
    fade_distance 0.9
    fade_color <0.5,0.8,0.6>
  }
}

#declare M_PseudoGlass2=
material {
  texture {
    pigment {rgbf <0.8,0.2,0.2,0.8>}
    finish {
      ambient 0.0
      diffuse 0.05
      specular 0.6
      roughness 0.005
      reflection { 0.1, 1.0 fresnel on }
      conserve_energy
    }
  }
  interior {
    ior 1.0
  }
}

sphere {
  <1.1,1,-1.3>, 1
  material { M_Glass }
  photons {
    target 1.0
    refraction on
    reflection on
  }
}

box {
  <2.4,0,-2.3>, <2.6,4,0.3>
  material { M_PseudoGlass2 }
  photons { target 1.0 refraction on reflection on }
}

This task depends upon

Closed by  Christoph Lipka (clipka)
Saturday, 19 June 2010, 12:25 GMT
Reason for closing:  Fixed
Additional comments about closing:  no beta tester feedback on this for quite a while, so I consider that good news.
Comment by Christoph Lipka (clipka) - Wednesday, 14 April 2010, 22:15 GMT
  • Field changed: Status (Investigating → Requires testing)
  • Field changed: Due in Version (Undecided → 3.70 beta 37)
  • Field changed: Percent Complete (0% → 100%)

fixed with change #4939

Loading...