POV-Ray

The Persistence of Vision Raytracer (POV-Ray).

This is the legacy Bug Tracking System for the POV-Ray project. Bugs listed here are being migrated to our github issue tracker. Please refer to that for new reports or updates to existing ones on this system.

Tasklist

FS#274 - light source fading doesn't work properly with area_illumination and subsurface scattering

Attached to Project: POV-Ray
Opened by Christoph Lipka (clipka) - Friday, 08 March 2013, 08:55 GMT
Last edited by William F Pokorny (wfpokorny) - Monday, 24 October 2016, 14:40 GMT
Task Type Definite Bug
Category Backend → Subsurface Scattering
Status Closed
Assigned To Christoph Lipka (clipka)
Operating System All
Severity Low
Priority Normal
Reported Version 3.70 RC7
Due in Version 3.70 release
Due Date Undecided
Percent Complete 100%
Votes 0
Private No

Details

When using fade_distance and fade_power in combination with area_illumination, the light source fading is not applied to materials with subsurface scattering; see the following code for an example:


#version 3.7;
global_settings {
  assumed_gamma 1.0
  mm_per_unit 10
  subsurface { samples 200,20 }
}

camera {
  right x*image_width/image_height
  angle 30
  location  <0,1.5,-4>
  look_at   <0,0,0>
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

plane {
  y, 0
  texture {
    pigment {
      checker
      color rgb <1.0, 0.8, 0.6>
      color rgb <1.0, 0.0, 0.0>
      scale 0.5
    }
  }
}

light_source {
  <50,50,50>
  color rgb 30
  area_light 5*x,5*y,17,17 adaptive 1 jitter circular orient
  area_illumination on
  fade_distance 10
  fade_power 2
}

cylinder {
  <0,0,0>, <0,0.2,0> 1
  texture {
    pigment { color rgb 1 }
    finish {
      ambient 0
      diffuse 0.7
      specular albedo 0.3
      reflection { 0.3 fresnel }
      conserve_energy
      subsurface { translucency 0.1 }
    }
  }
  interior { ior 1.5 }
}

sphere {
  <0,0.4,0>, 0.2
  texture {
    pigment { color rgb <1,0.6,0.0> }
    finish {
      ambient 0
      diffuse 0.0
      specular albedo 0.8 metallic
      reflection { 1.0 metallic }
      conserve_energy
    }
  }
}

This task depends upon

Closed by  William F Pokorny (wfpokorny)
Monday, 24 October 2016, 14:40 GMT
Reason for closing:  Fixed
Additional comments about closing:  Replicated original issue with 3.7.0 RC7 code. Confirmed fix still part of the current 3.7.1 master branch.
Comment by Christoph Lipka (clipka) - Friday, 08 March 2013, 08:57 GMT
  • Field changed: Status (Investigating → Requires testing)
  • Field changed: Percent Complete (0% → 100%)

fixed with change #5846

Loading...